***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jun 06, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BAV170 A K 
.param
+vc0 = 2.372e-10	 vc1 = 5.027e-12	 vc2 = 8.267e-12	 vc3 = 9.574e-1
+tc1 = 2.546e-2		 tc2 = 9.987e-3		 tc3 = 1.194e-2		 tc4 = 1.194e-2
.func ir(v) {(vc0+vc1*v)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc2*v^vc3*(1.0+tc3*(temp-25)*exp(tc4*(temp-25))))}
d1 A K diode
g1 K A value = {ir(v(K,A))}
.model diode d
***** flag parameter *****
+level = 1
***** dc model parameter *****
+ is = 8.068e-13	   n = 1.394		  rs = 7.650e-1		 ;ikf = 18.915
+ibv = 0.1e-3		 nbv = 1			  bv = 275
***** capacitance parameter *****
+cjo = 2.022e-12	   m = 1.950e-1		  vj = 1.752e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25			  eg = 1.130		 xti = 3
+trs1 = 5.051e-4	trs2 = 7.825e-6
.ends BAV170
*$
